CD-ROM Magazine 28 Bonus/CDRomMagazine-SoftKey-ArtPassion-FrenchVersion-Win31Mac.bin/data/artmain.dir/00096_Script_QTVR Win Scripts

Text File | 1996-06-05 | 22KB | 582 lines

-- ⌐ 1992-1995 Apple Computer, Inc.  All rights reserved.

--========================================================================
-- Routines for initializing and cleaning up the Director movie.
--------------------------------------------------------------------------


--====================================================================
-- StartMovie
--
-- Runs at movie start time.  Initializes key globals and opens the
-- external library.
----------------------------------------------------------------------
on InitQTVRWin
  global gPathName, gLastTimeRollover, gPanoFrame
  put empty into gPathName
  put false into gLastTimeRollover
  put empty into gPanoFrame

  -- Open the DLL which contains the QTVRW XObject

  openxlib the pathname & "ARTMAINA\QTVRW.QTC"

  -- Ensure that QuickTime is initialized by opening and
  -- closing a QTVRW object.  This is only necessary to deal
  -- with some harmless problems that Dr. Watson will detect
  -- if a QuickTime movie is not opened before you close
  -- the QTVRW.QTC xlibrary and exit the projector.  (Note
  -- that these problems do not occur in Director itself.)  If
  -- you can guarantee to open a QuickTime movie before exiting,
  -- these lines are not necessary.

  set tInitObj = QTVRW (mNew, "Nav")
  if objectP (tInitObj) then tInitObj (mDispose)

  -- Create callback factories for panoramas
  global gPanoCallbackFactory, gTestCallbackFactory
  put SampleCallbacksWin(mNew) into gPanoCallbackFactory
  -- put TestCallbacksWin(mNew) into gTestCallbackFactory

end InitQTVRWin

--====================================================================
-- StopMovie
--
-- Runs at movie stop time.  Closes any open pano or nav movies.
-- Closes the external code library.
----------------------------------------------------------------------
on disposeQTVRWin
  -- Close any open panoramic or object movies
  ClosePanoMovieWin
  CloseNavMovieWin

  -- Close the DLL
  closexlib the pathname & "ARTMAINA\QTVRW.QTC"

  global gPanoCallbackFactory, gTestCallbackFactory
  if objectP(gPanoCallbackFactory) then gPanoCallbackFactory(mDispose)
  -- if objectP(gTestCallbackFactory) then gTestCallbackFactory(mDispose)

end disposeQTVRWin


--========================================================================
-- Routines for managing navigable movies
--------------------------------------------------------------------------


--========================================================================
-- OpenNavMovie:
--      pFilename is the full file path of the file
--      pSpriteNum is the sprite associated with the direct Nav Movie
--      pShowOnOpen is a boolean for showing the movie on screen immediately
--
-- Opens the file pFileName as a nav movie at the top left corner of sprite
-- pSpriteNum.  Shows it on the screen as dictated by pShowOnOpen.
--------------------------------------------------------------------------
on OpenNavMovie pFilename, pSpriteNum, pShowOnOpen
  global gNavMovieObj

  -- These routines are structured similarly to the Macintosh-based routines,
  -- and the use of a single global gNavMovieObj to hold the instance reference
  -- restricts usage by allowing only one navigable movie to be open at a time.

  -- Close any other open nav movie.
  CloseNavMovieWin

  -- Load in the movie.  Assume the underlying sprite is the correct size.
  set gNavMovieObj = QTVRW (mNew, "Nav")
  if not objectP(gNavMovieObj) then
    put "Unable to create new Nav instance"
    beep
    exit
  end if

  put gNavMovieObj (mOpenMovie, pFileName, the left of sprite pSpriteNum ¼
      & "," & the top of sprite pSpriteNum) into tResultCode
  if tResultCode = 0 then
    put "Unable to open navmovie"
    gNavMovieObj (mDispose)
    beep
    exit
  end if

  if pShowOnOpen then
    -- Show the poster frame of the nav movie on screen
    gNavMovieObj (mUpdate)
  end if
end OpenNavMovie


--========================================================================
-- ShowNavMovie
--
-- Updates the nav movie display on screen.
--------------------------------------------------------------------------
on ShowNavMovie
  global gNavMovieObj
  if objectP (gNavMovieObj)  then
    gNavMovieObj (mUpdate)
  end if
end ShowNavMovie


--========================================================================
-- SetNavMovieView:
--      pHPan is the horizontal pan angle
--      pVPan is the vertical pan angle
--
-- Sets the nav movie view to the specified pan angles.
--------------------------------------------------------------------------
on SetNavMovieView pHPan, pVPan
  global gNavMovieObj
  if objectP (gNavMovieObj) then
    gNavMovieObj (mSetHPanAngle, string(pHPan))
    gNavMovieObj (mSetVPanAngle, string(pVPan))
  end if
end SetNavMovieView


--========================================================================
-- CloseNavMovieWin
--
-- Disposes an open nav movie.  This does not remove the image from
-- the screen.
--------------------------------------------------------------------------
on CloseNavMovieWin
  global gNavMovieObj
  if objectP (gNavMovieObj) then
    gNavMovieObj (mDispose)
  end if
end CloseNavMovieWin


--========================================================================
-- NavFrameScript
--      pSpriteNum is the sprite which lies under the nav movie
--
-- When run frequently, provides cursor feedback over the nav movie
-- and handles mouse down and keyboard actions.
--------------------------------------------------------------------------
on NavFrameScript pSpriteNum
  global gNavMovieObj
  if objectP (gNavMovieObj) then
    if rollover (pSpriteNum) then
      gNavMovieObj (mMouseOver)
      cursor 200
      cursor -1
    else
      gNavMovieObj(mIdle)
    end if
  end if
end NavFrameScript


--========================================================================
-- Routines for managing panoramic movies
--------------------------------------------------------------------------


--========================================================================
-- OpenPanoMovieWin
--      pFilename is the full file path of the file
--      pSpriteNum is the sprite associated with the direct Pano Movie
--      pShowOnOpen is a boolean for showing the movie on screen immediately
--
-- Opens the file pFileName as a panoramic movie, and sets up callback
-- handlers as specified.  Updates the screen with the movie's default
-- view if requested by pShowOnOpen
--------------------------------------------------------------------------
on OpenPanoMovieWin pFileName, pSpriteNum, pShowOnOpen
  global gPanoMovieObj, gPathName

  -- These routines are structured similarly to the Macintosh-based routines,
  -- and the use of a single global gPanoMovieObj to hold the instance reference
  -- restricts usage by allowing only one navigable movie to be open at a time.

  -- Close any other open pano movie.
  ClosePanoMovieWin

  set gPanoMovieObj = QTVRW (mNew, "Pan")
  if not objectP(gPanoMovieObj) then
    put "Unable to create new Pan instance"
    beep
    exit
  end if

  -- Load in the movie.  Assume the underlying sprite is the correct size.
  put gPanoMovieObj (mOpenMovie, pFileName, the left of sprite pSpriteNum ¼
      & "," & the top of sprite pSpriteNum) into tResultCode
  if tResultCode = 0 then
    put "Unable to open panomovie"
    gPanoMovieObj (mDispose)
    beep
    exit
  end if

  put ExtractPathNameWin(pFileName) into gPathName

  InitPanoCallbacksWin

  if pShowOnOpen then
    gPanoMovieObj (mUpdate)
  end if

end OpenPanoMovieWin


--========================================================================
-- InitPanoCallbacksWin
--
-- Initializes the callbacks used for panoramic movies.
--------------------------------------------------------------------------
on InitPanoCallbacksWin
  global gPanoMovieObj, gPanoCallbackFactory
  if objectP(gPanoMovieObj) and objectP(gPanoCallbackFactory) then
    -